clacks/lib/clacks/inbox.ex

defmodule Clacks.Inbox do
  require Logger
  alias Clacks.{Repo, Activity, Object, Actor, ActivityPub}

  defp store_activity(%{"actor" => actor, "id" => ap_id} = activity, local \\ false)
       when is_binary(actor) do
    changeset =
      Activity.changeset(Activity.get_cached_by_ap_id(ap_id) || %Activity{}, %{
        data: activity,
        local: local,
        actor: actor
      })

    Repo.insert_or_update(changeset)
  end

  @spec handle(activity :: map()) :: :ok | {:error, reason :: any()}

  def handle(%{"type" => "Create", "object" => object} = activity) do
    changeset = Object.changeset(%Object{}, %{data: object})

    case Repo.insert(changeset) do
      {:error, changeset} ->
        Logger.error("Couldn't store object: #{inspect(changeset)}")
        {:error, "Couldn't store changeset"}

      {:ok, _object} ->
        case store_activity(activity) do
          {:error, changeset} ->
            Logger.error("Couldn't store Create activity: #{inspect(changeset)}")
            {:error, "Couldn't store Create activity"}

          {:ok, _activity} ->
            :ok
        end
    end
  end

  def handle(%{"type" => "Follow", "object" => followed_id, "actor" => follower_id} = activity)
      when is_binary(followed_id) do
    followed = Actor.get_by_ap_id(followed_id)
    follower = Actor.get_by_ap_id(follower_id)

    store_activity(activity)

    new_followers = [follower_id | followed.followers] |> Enum.uniq()
    changeset = Actor.changeset(followed, %{followers: new_followers})

    case Repo.update(changeset) do
      {:error, changeset} ->
        Logger.error("Couldn't store updated followers: #{inspect(changeset)}")
        {:error, "Couldn't store updated followers"}

      {:ok, _followed} ->
        accept = ActivityPub.accept_follow(activity)

        case store_activity(accept, true) do
          {:error, changeset} ->
            Logger.error("Couldn't store Accept activity: #{inspect(changeset)}")
            {:error, "Couldn't store Accept activity"}

          {:ok, _accept} ->
            ActivityPub.Federator.federate(accept, follower.data["inbox"])
        end
    end
  end

  def handle(
        %{
          "type" => "Accept",
          "actor" => followee_id,
          "object" => %{"type" => "Follow", "id" => follow_activity_id, "actor" => follower_id}
        } = activity
      ) do
    followee = Actor.get_by_ap_id(followee_id)
    follower = Actor.get_by_ap_id(follower_id)

    store_activity(activity)

    follow_activity = Activity.get_cached_by_ap_id(follow_activity_id)

    changeset =
      Activity.changeset(follow_activity, %{
        data: %{follow_activity.data | "state" => "accepted"}
      })

    case Repo.update(changeset) do
      {:error, changeset} ->
        Logger.error("Couldn't store updated Follow activity: #{inspect(changeset)}")
        {:error, "Couldn't store updated Follow activity"}

      {:ok, _follow_activity} ->
        new_followers = [follower_id | followee.followers] |> Enum.uniq()
        changeset = Actor.changeset(followee, %{followers: new_followers})

        case Repo.update(changeset) do
          {:error, changeset} ->
            Logger.error("Couldn't store updated followers: #{inspect(changeset)}")
            {:error, "Couldn't store updated followers"}

          {:ok, _followee} ->
            :ok
        end
    end
  end

  # as a fallback, just store the activity
  def handle(activity) do
    case store_activity(activity) do
      {:error, changeset} ->
        Logger.error("Could not store activity: #{inspect(changeset)}")
        {:error, "Could not store activity"}

      {:ok, _activity} ->
        :ok
    end
  end
end